9eb0f53db1
* Allow changing audio device on the fly while in a server * Use default audio device if device in config doesn't exist * Automatically change audio device to default when current one is invalid * Destroy Qt Multimedia support It was decided that there was not enough attention being given to Qt Multimedia support to justify its continued maintenance simply as a libre alternative to BASS. While substantial changes to audio were being made in 2.8, the Qt Multimedia support code fell behind in disrepair. It's clear that there is no vested interest in implementing audio features twice for the sake of licensing. When it's time to switch to another audio library, it will be done unilaterally. * CI: Use BASS for Linux build Co-authored-by: oldmud0 <oldmud0@users.noreply.github.com>
59 lines
1.5 KiB
Prolog
59 lines
1.5 KiB
Prolog
QT += core gui widgets network
|
|
|
|
TARGET = Attorney_Online
|
|
TEMPLATE = app
|
|
|
|
VERSION = 2.8.4.0
|
|
|
|
INCLUDEPATH += $$PWD/include
|
|
DESTDIR = $$PWD/bin
|
|
OBJECTS_DIR = $$PWD/build
|
|
MOC_DIR = $$PWD/build
|
|
|
|
SOURCES += $$files($$PWD/src/*.cpp)
|
|
HEADERS += $$files($$PWD/include/*.h)
|
|
|
|
LIBS += -L$$PWD/lib
|
|
|
|
# Uncomment to enable Discord Rich Presence
|
|
# DEFINES += DISCORD
|
|
|
|
contains(DEFINES, DISCORD) {
|
|
LIBS += -ldiscord-rpc
|
|
}
|
|
|
|
# As of 2.8.5, BASS and BASSOPUS are required for all platforms. Qt Multimedia
|
|
# is no longer an option due to outdated code and lack of versatility.
|
|
# Download at un4seen.com and place the DLLs in the "lib" and "bin" folders.
|
|
DEFINES += BASSAUDIO
|
|
LIBS += -lbass
|
|
LIBS += -lbassopus
|
|
|
|
macx:LIBS += -framework CoreFoundation -framework Foundation -framework CoreServices
|
|
|
|
CONFIG += c++14
|
|
|
|
RESOURCES += resources.qrc
|
|
|
|
TRANSLATIONS = resource/translations/ao_en.ts \
|
|
resource/translations/ao_jp.ts \
|
|
resource/translations/ao_de.ts \
|
|
resource/translations/ao_ru.ts \
|
|
resource/translations/ao_es.ts \
|
|
resource/translations/ao_pt.ts \
|
|
resource/translations/ao_pl.ts
|
|
|
|
win32:RC_ICONS = resource/logo_ao2.ico
|
|
macx:ICON = resource/logo_ao2.icns
|
|
|
|
android:DISTFILES += \
|
|
android/AndroidManifest.xml \
|
|
android/build.gradle \
|
|
android/gradle/wrapper/gradle-wrapper.jar \
|
|
android/gradle/wrapper/gradle-wrapper.properties \
|
|
android/gradlew \
|
|
android/gradlew.bat \
|
|
android/res/values/libs.xml
|
|
|
|
ANDROID_PACKAGE_SOURCE_DIR = $$PWD/android
|