f0a5e48f5c
* Replace TCP Serversocket with Websocket * Have TCP sockets live harmoniously with WS "like 5 lines" yeah probably lost a bet. * Update .gitlab-ci.yml * hack to fix favorites * Add support for websockets in the favorites list (serverlist.txt) Make "add_favorite_server" remember the socket type * Preserve old serverlist style This will keep new entries compatible with 2.9 and prior clients. Makes parsing the list easier too. * Add lookup table and correct write code to use lowercase * I have no idea what a lookup table is, but this looks close enough * Fix lookup table * Otherwise backend selection behaviour is inverted * clang-tidy had one job * Yet it did not do it. Co-authored-by: oldmud0 <oldmud0@users.noreply.github.com> * const p_data * Switch serverlist.txt to an ini format * Fixes an Omni bug where : would split the servername * Utilises internally QSettings properly for low parsing effort and clear structure * Automatically migrates the legacy serverlist.txt to favorite_servers.ini * Pleases my OCD * Replace sample serverlist. Co-authored-by: oldmud0 <oldmud0@users.noreply.github.com> Co-authored-by: stonedDiscord <Tukz@gmx.de> Co-authored-by: Alex Noir <Varsash@gmail.com>
74 lines
1.8 KiB
Prolog
74 lines
1.8 KiB
Prolog
QT += core gui widgets network websockets
|
|
|
|
TARGET = Attorney_Online
|
|
TEMPLATE = app
|
|
|
|
VERSION = 2.10.0.0
|
|
|
|
INCLUDEPATH += $$PWD/include
|
|
DESTDIR = $$PWD/bin
|
|
OBJECTS_DIR = $$PWD/build
|
|
MOC_DIR = $$PWD/build
|
|
|
|
SOURCES += $$files($$PWD/src/*.cpp)
|
|
HEADERS += $$files($$PWD/include/*.h)
|
|
|
|
LIBS += -L$$PWD/lib
|
|
QMAKE_LFLAGS += -Wl,-rpath,"'\$$ORIGIN/lib'"
|
|
|
|
# Uncomment for verbose network logging
|
|
# DEFINES += DEBUG_NETWORK
|
|
|
|
# Uncomment for verbose animation logging
|
|
# DEFINES += DEBUG_MOVIE
|
|
|
|
# Uncomment for building with debug symbols
|
|
# CONFIG += debug
|
|
|
|
# Uncomment to enable Discord Rich Presence
|
|
# DEFINES += DISCORD
|
|
|
|
contains(DEFINES, DISCORD) {
|
|
LIBS += -ldiscord-rpc
|
|
}
|
|
|
|
# As of 2.8.5, BASS and BASSOPUS are required for all platforms. Qt Multimedia
|
|
# is no longer an option due to outdated code and lack of versatility.
|
|
# Download at un4seen.com and place the DLLs in the "lib" and "bin" folders.
|
|
DEFINES += BASSAUDIO
|
|
LIBS += -lbass
|
|
LIBS += -lbassopus
|
|
LIBS += -lbassmidi
|
|
|
|
macx:LIBS += -framework CoreFoundation -framework Foundation -framework CoreServices
|
|
|
|
win32:LIBS += -ladvapi32
|
|
|
|
CONFIG += c++17
|
|
|
|
RESOURCES += resources.qrc
|
|
|
|
TRANSLATIONS = resource/translations/ao_en.ts \
|
|
resource/translations/ao_jp.ts \
|
|
resource/translations/ao_de.ts \
|
|
resource/translations/ao_ru.ts \
|
|
resource/translations/ao_es.ts \
|
|
resource/translations/ao_pt.ts \
|
|
resource/translations/ao_pl.ts \
|
|
resource/translations/ao_it.ts
|
|
|
|
win32:RC_ICONS = resource/logo_ao2.ico
|
|
macx:ICON = resource/logo_ao2.icns
|
|
|
|
android:QT += androidextras
|
|
|
|
android:DISTFILES += \
|
|
android/AndroidManifest.xml \
|
|
android/gradle.properties \
|
|
android/gradle/wrapper/gradle-wrapper.jar \
|
|
android/gradle/wrapper/gradle-wrapper.properties \
|
|
android/gradlew \
|
|
android/gradlew.bat
|
|
|
|
ANDROID_PACKAGE_SOURCE_DIR = $$PWD/android
|