d87371b65e
* try this matrix thing * syntax error * use my own qt installer so it actually works * allow changing path * whoops cant have it twice * get the right version of discord rpc * get correct bass * try to fix windows * overwrite bass files * forgot to delete these * here's your version bro * what did we even use catch2 for?? * linux doesnt have a c folder * android bass * switch from cmake to qmake * opus dylib * we don't install * put bass in a subfolder so we don't build the stupid examples * was using wrong arch for android * fix up gitignore * get correct artifact folder * lets hope qmake will ignore the ABI for all the other platforms * use platform name for artifact * copy dlls into bin folder * lmao i yeeted the folder * create folder * use more recent mingw * windows uses dlls * 2017 doesn't work * our libs are 64 bit * install msvc * shitty ms documentation * ok ms * wrong directory for deploy * copy apng * use correct image for msvc2019 * deploy android * 32bit windows it is * adroideploy * try this * Update build.yml * move libs * armeabi-v7a * fix android build files * only get linux bass for linux * don't try to install discord on android * deploy mac * get rid of double permission warning * define filename for APK * add mac dependencies * put android bass in the correct folder * mac apng * android apng * remove old CI * ask for storage permissions * qt bug .......... * update clang-tidy-review * update everything * fuck you lukka * fuck you jurplel for merging that shitty PR that broke everything * give it what it wants * Update clang-tidy-review.yml * github is failing it because it's too big * wait for the user and request a proper permission string * underscore moment * use write external storage instead * try this instead * 082 fails with docker again
73 lines
1.8 KiB
Prolog
73 lines
1.8 KiB
Prolog
QT += core gui widgets network
|
|
|
|
TARGET = Attorney_Online
|
|
TEMPLATE = app
|
|
|
|
VERSION = 2.10.0.0
|
|
|
|
INCLUDEPATH += $$PWD/include
|
|
DESTDIR = $$PWD/bin
|
|
OBJECTS_DIR = $$PWD/build
|
|
MOC_DIR = $$PWD/build
|
|
|
|
SOURCES += $$files($$PWD/src/*.cpp)
|
|
HEADERS += $$files($$PWD/include/*.h)
|
|
|
|
LIBS += -L$$PWD/lib
|
|
QMAKE_LFLAGS += -Wl,-rpath,"'\$$ORIGIN/lib'"
|
|
|
|
# Uncomment for verbose network logging
|
|
# DEFINES += DEBUG_NETWORK
|
|
|
|
# Uncomment for verbose animation logging
|
|
# DEFINES += DEBUG_MOVIE
|
|
|
|
# Uncomment for building with debug symbols
|
|
# CONFIG += debug
|
|
|
|
# Uncomment to enable Discord Rich Presence
|
|
# DEFINES += DISCORD
|
|
|
|
contains(DEFINES, DISCORD) {
|
|
LIBS += -ldiscord-rpc
|
|
}
|
|
|
|
# As of 2.8.5, BASS and BASSOPUS are required for all platforms. Qt Multimedia
|
|
# is no longer an option due to outdated code and lack of versatility.
|
|
# Download at un4seen.com and place the DLLs in the "lib" and "bin" folders.
|
|
DEFINES += BASSAUDIO
|
|
LIBS += -lbass
|
|
LIBS += -lbassopus
|
|
LIBS += -lbassmidi
|
|
|
|
macx:LIBS += -framework CoreFoundation -framework Foundation -framework CoreServices
|
|
|
|
win32:LIBS += -ladvapi32
|
|
|
|
CONFIG += c++17
|
|
|
|
RESOURCES += resources.qrc
|
|
|
|
TRANSLATIONS = resource/translations/ao_en.ts \
|
|
resource/translations/ao_jp.ts \
|
|
resource/translations/ao_de.ts \
|
|
resource/translations/ao_ru.ts \
|
|
resource/translations/ao_es.ts \
|
|
resource/translations/ao_pt.ts \
|
|
resource/translations/ao_pl.ts
|
|
|
|
win32:RC_ICONS = resource/logo_ao2.ico
|
|
macx:ICON = resource/logo_ao2.icns
|
|
|
|
android:QT += androidextras
|
|
|
|
android:DISTFILES += \
|
|
android/AndroidManifest.xml \
|
|
android/gradle.properties \
|
|
android/gradle/wrapper/gradle-wrapper.jar \
|
|
android/gradle/wrapper/gradle-wrapper.properties \
|
|
android/gradlew \
|
|
android/gradlew.bat
|
|
|
|
ANDROID_PACKAGE_SOURCE_DIR = $$PWD/android
|