0be8d0f5ae
* stop magic number spam * forgot to remove avoid * Update .clang-format * yeet qt translations and unused image formats * also remove bearer and styles * remove another svg dll * create dmg on mac * forgot .app * delete folder after packing * skip runtime webkit and opengl * switch back to fixed qt setup * try installing the NDK * update discord rpc includes * enable discord in CI builds * copypaste lmao * windows doesn't have export * forgot the quotes * guess i'm not root * downgrade ubuntu * lets hope ubuntu 18 comes with android ndk * it doesn't * try to update libpng * script wasn't executable * downgrade android * typo * use qmake to enable discord * exit code 101 very funny qmake * its in defines not just true * can i use qmake like this? * add discord * exclude android from discord * android runs on linux after all
76 lines
1.9 KiB
Prolog
76 lines
1.9 KiB
Prolog
QT += core gui widgets network websockets
|
|
|
|
TARGET = Attorney_Online
|
|
TEMPLATE = app
|
|
|
|
VERSION = 2.10.0.0
|
|
|
|
INCLUDEPATH += $$PWD/include
|
|
DESTDIR = $$PWD/bin
|
|
OBJECTS_DIR = $$PWD/build
|
|
MOC_DIR = $$PWD/build
|
|
|
|
SOURCES += $$files($$PWD/src/*.cpp)
|
|
HEADERS += $$files($$PWD/include/*.h)
|
|
|
|
LIBS += -L$$PWD/lib
|
|
QMAKE_LFLAGS += -Wl,-rpath,"'\$$ORIGIN/lib'"
|
|
|
|
# Uncomment for verbose network logging
|
|
# DEFINES += DEBUG_NETWORK
|
|
|
|
# Uncomment for verbose animation logging
|
|
# DEFINES += DEBUG_MOVIE
|
|
|
|
# Uncomment for building with debug symbols
|
|
# CONFIG += debug
|
|
|
|
# Uncomment to enable Discord Rich Presence
|
|
# DEFINES += DISCORD
|
|
|
|
contains(DEFINES, DISCORD) {
|
|
win32:LIBS += -ldiscord-rpc
|
|
linux:!android:LIBS += -ldiscord-rpc
|
|
mac:LIBS += -ldiscord-rpc
|
|
}
|
|
|
|
# As of 2.8.5, BASS and BASSOPUS are required for all platforms. Qt Multimedia
|
|
# is no longer an option due to outdated code and lack of versatility.
|
|
# Download at un4seen.com and place the DLLs in the "lib" and "bin" folders.
|
|
DEFINES += BASSAUDIO
|
|
LIBS += -lbass
|
|
LIBS += -lbassopus
|
|
LIBS += -lbassmidi
|
|
|
|
macx:LIBS += -framework CoreFoundation -framework Foundation -framework CoreServices
|
|
|
|
win32:LIBS += -ladvapi32
|
|
|
|
CONFIG += c++17
|
|
|
|
RESOURCES += resources.qrc
|
|
|
|
TRANSLATIONS = resource/translations/ao_en.ts \
|
|
resource/translations/ao_jp.ts \
|
|
resource/translations/ao_de.ts \
|
|
resource/translations/ao_ru.ts \
|
|
resource/translations/ao_es.ts \
|
|
resource/translations/ao_pt.ts \
|
|
resource/translations/ao_pl.ts \
|
|
resource/translations/ao_it.ts
|
|
|
|
win32:RC_ICONS = resource/logo_ao2.ico
|
|
macx:ICON = resource/logo_ao2.icns
|
|
|
|
android:QT += androidextras
|
|
|
|
android:DISTFILES += \
|
|
android/AndroidManifest.xml \
|
|
android/gradle.properties \
|
|
android/gradle/wrapper/gradle-wrapper.jar \
|
|
android/gradle/wrapper/gradle-wrapper.properties \
|
|
android/gradlew \
|
|
android/gradlew.bat
|
|
|
|
ANDROID_PACKAGE_SOURCE_DIR = $$PWD/android
|